/ Forside/ Teknologi / Operativsystemer / MS Windows / Spørgsmål
Login
Glemt dit kodeord?
Brugernavn 

Kodeord  


Reklame
Top 10 brugere
MS Windows
#NavnPoint
Klaudi 69375
o.v.n. 67550
refi 58409
Manse9933 45149
tedd 44737
molokyle 40677
miritdk 38357
briani 27239
BjarneD 26414
10  pallebhan.. 24310
Lav liste af mapper/filer.
Fra : WoflerPro
Vist : 369 gange
50 point
Dato : 01-02-06 22:08

Hej.

Jeg har kørt alle mine musik Cd'er ind på min PC.
Og bruger så den til at spille min musik fra.

De fleset musik afspiller har jo et meget overskueligt bibliotek til nemt at finde det man vil høre.

Jeg har lavet en bat-fil der laver en txt fil med en liste af mapperne.

Her er indholdet af batfilen:
Kode
cd musik
cd Albums

tree /a > ..\..\Albumliste.txt


Jeg kunne dog godt tænke mig at listen også indeholder dato for hvornår mapperne er blevet tilføjet og evt. sorteret efter dato.

Er det muligt og hvordan laver jeg det i bat-filen..?

Andre forslag i stedet for at bruge bat-fil evt et lille program der kan gøre det... Er også meget velkommen..?

Mvh
WoflerPro

 
 
Kommentar
Fra : BertelBrander


Dato : 01-02-06 22:39

Jeg tror ikke du kan gøre det med tree kommandoen.

Men du kan prøve med:
for /F "delims=;" %%I in ('dir /S /B /AD') do @echo %%~tI %%I>>..\..\Albumliste.txt

Hvis output ser fornuftigt ud kan vi godt få den til at sortere efter dato.

Kommentar
Fra : WoflerPro


Dato : 01-02-06 23:26

Hej Bertel.

Jo det ser brugbart ud.
Hvordan får jeg den så til at sortere efter dato...??

Kommentar
Fra : BertelBrander


Dato : 01-02-06 23:31

Jeg skal lige vide hvordan dit dato og tid format ser ud.
Her skriver den:
29-01-2006 19:59 Whatever

Men det kan godt variere mellem windows versioner.

Og hvordan vil du gerne have at output ser ud når vi er færdige?

Kommentar
Fra : WoflerPro


Dato : 01-02-06 23:37

Her ser det sådan ud:

05-01-2006 22:01 M:\

Det er hvis det samme som hos dig..

Det ser ikke ud som om den liste jeg har nu er sorteet på nogen måde..
Hvis nu jeg vil lave to bat-filer.

1. Der sortere alfabetisk
2. Der sortere efter dato

Eller kan det lægges ind i den samme fil så den ad sig selv laver to txt filer..?

Kommentar
Fra : WoflerPro


Dato : 01-02-06 23:50

Lige en ting til....

Når jeg køre batfilen igen. Skrives der videre på TXT filen.
Er det muligt at overskrive den.... Eller skal jeg bare venne mig til at slette txt filen inden jeg køre batfilen igen...?

Kommentar
Fra : BertelBrander


Dato : 01-02-06 23:51

Jeg laver det så den sletter filerne inden den starter.
Jeg bliver ikke færdig før imorgen, det er sent.

Accepteret svar
Fra : BertelBrander

Modtaget 50 point
Dato : 02-02-06 00:13

Nå, jeg fik det færdigt.

Den laver to filer:
MappelistDato.txt der indeholder alle filnavne sorteret efter dato, ældst først
MappelistNavn.txt der indeholder alle filnavne sorteret efter Navn

Du kan ændre deres navn og placering med:
Set DatoFil=MappelistDato.txt
Set NavneFil=MappelistNavn.txt

Du kan sætte dine cd kommandoer ind i toppen, efter @echo off

--- Resten er koden ---
@echo off
setlocal
set TmpFile1="%temp%\mappelst1.tmp"
set TmpFile2="%temp%\mappelst2.tmp"
set TmpFile3="%temp%\mappelst3.tmp"

Set DatoFil=MappelistDato.txt
Set NavneFil=MappelistNavn.txt

if exist %TmpFile1% del %TmpFile1%
if exist %TmpFile2% del %TmpFile2%
if exist %TmpFile3% del %TmpFile3%
if exist %DatoFil% del %DatoFil%
if exist %NavneFil% del %NavneFil%

for /F "delims=;" %%I in ('dir /S /B /AD') do call :Process1 %%~tI "%%I"

sort %TmpFile1%>%TmpFile2%
for /F "tokens=1,2,3,4,*" %%A in (%TmpFile2:"=%) do echo %%C-%%B-%%A %%D %%~E>>%DatoFil%

sort %TmpFile3%>%TmpFile2%
for /F "tokens=1,2 delims=;" %%A in (%TmpFile2:"=%) do @echo %%B%%~A>>%NavneFil%

goto :eof

:Process1
set Dato=%1
set tid=%2
set Name=%~3

for /F "tokens=1,2,3 delims=-" %%A in ("%Dato%") do (
set Aar=%%C
set Maaned=%%B
set Dag=%%A
)

echo %Aar% %Maaned% %Dag% %Tid% %Name%>>%TmpFile1%
echo "%Name%";%Dato% %Tid% >>%TmpFile3%
goto :eof

Godkendelse af svar
Fra : WoflerPro


Dato : 02-02-06 00:34

Tak for svaret BertelBrander.

Tuuusind tak for meget hurtig og meget god hjælp...
Det virker HELT perfekt og akurart som jeg havde ønsket det skulle...


Du har været til meget stor hjælp.

Mvh
WoflerPro


Du har følgende muligheder
Eftersom du ikke er logget ind i systemet, kan du ikke skrive et indlæg til dette spørgsmål.

Hvis du ikke allerede er registreret, kan du gratis blive medlem, ved at trykke på "Bliv medlem" ude i menuen.
Søg
Reklame
Statistik
Spørgsmål : 173466
Tips : 31650
Nyheder : 719565
Indlæg : 6382375
Brugere : 218248

Månedens bedste
Årets bedste
Sidste års bedste