---

Er der nogen her der kan give mig et simpelt eksempel på hvordan man bruger
MSMQ fra VB?

---

"Rudi Hansen" <Rudi.Hansen@birkelan.dk> wrote in message
news:_v1N8.29220$N46.1048339@news010.worldonline.dk...
> Er der nogen her der kan give mig et simpelt eksempel på hvordan man
bruger
> MSMQ fra VB?
>
>
Jeg har da 2 eksempler her. Det første opretter en ny kø og indsætter en
meddelse mens det andet eksempel henter fra denne kø. Håber du kan bruge det
:)

Private Sub SendMessage_Click()

On Error GoTo SendMessageErr

Dim oQInfo As MSMQ.MSMQQueueInfo

Dim oQueue As MSMQ.MSMQQueue

Dim oMessage As MSMQMessage



' Initialiser MSMQQueueInfo objektet

Set oQInfo = New MSMQQueueInfo



oQInfo.PathName = ".\PRIVATE$\Test"



' Laver nu en queue

oQInfo.Label = "Test Queue"

oQInfo.Create

' Åbner queueen så vi kan sende til den

Set oQueue = oQInfo.Open(MQ_SEND_ACCESS, MQ_DENY_NONE)

' Hvis det lykkedes at åbne

If oQueue.IsOpen Then

' Initialisere MSMQMessage objektet

Set oMessage = New MSMQMessage

With oMessage

.Label = "Test message"

.Priority = 7 ' Default er 3

.Body = "Vi tester"

.Send oQueue

End With

Else

' Det lykkedes ikke at åbne queueen

MsgBox "Det lykkedes ikke at åbne queueen."

Exit Sub

End If

' hvis alt er gået godt lukker vi queueen

oQueue.Close

MsgBox "En message er sendt."

Exit Sub

SendMessageErr:

' Hvis queuen findes i forvejen fortsætter vi.

If Err.Number = MQ_ERROR_QUEUE_EXISTS Then

Resume Next

End If

' Håndter andre fejl

MsgBox Err.Description

End Sub





Og her henter vi fra vores kø:



Private Sub Hentmessage_Click()

On Error GoTo HentmessageErr

Dim oQinfo As MSMQ.MSMQQueueInfo

Dim oQueue As MSMQ.MSMQQueue

Dim oMessage As MSMQ.MSMQMessage



Set oQinfo = New MSMQQueueInfo

oQinfo.PathName = ".\PRIVATE$\Test"

' Åbner queueen så vi kan modtage

Set oQueue = oQinfo.Open(MQ_RECEIVE_ACCESS, MQ_DENY_NONE)

' Hvis det lykkedesat åbne queueen henter vi en message

If oQueue.IsOpen Then

Set oMessage = oQueue.ReceiveCurrent(ReceiveTimeout:=1000)

Debug.Print "Label: " & oMessage.Label & vbCrLf

Debug.Print "Body: " & oMessage.Body

Else

MsgBox "Det lykkedes ikke at åbne queueen"

Exit Sub

End If

oQueue.Close

Exit Sub

HentmessageErr:

MsgBox Err.Description

End Sub